mirror of https://github.com/arendst/Tasmota.git
61 lines
3.1 KiB
Plaintext
61 lines
3.1 KiB
Plaintext
// ---------------------------------------------------------------------------
|
|
// Calculate a ping median using the ping_timer() method.
|
|
// ---------------------------------------------------------------------------
|
|
|
|
#include <NewPing.h>
|
|
|
|
#define ITERATIONS 5 // Number of iterations.
|
|
#define TRIGGER_PIN 12 // Arduino pin tied to trigger pin on ping sensor.
|
|
#define ECHO_PIN 11 // Arduino pin tied to echo pin on ping sensor.
|
|
#define MAX_DISTANCE 200 // Maximum distance (in cm) to ping.
|
|
#define PING_INTERVAL 33 // Milliseconds between sensor pings (29ms is about the min to avoid cross-sensor echo).
|
|
|
|
unsigned long pingTimer[ITERATIONS]; // Holds the times when the next ping should happen for each iteration.
|
|
unsigned int cm[ITERATIONS]; // Where the ping distances are stored.
|
|
uint8_t currentIteration = 0; // Keeps track of iteration step.
|
|
|
|
NewPing sonar(TRIGGER_PIN, ECHO_PIN, MAX_DISTANCE); // NewPing setup of pins and maximum distance.
|
|
|
|
void setup() {
|
|
Serial.begin(115200);
|
|
pingTimer[0] = millis() + 75; // First ping starts at 75ms, gives time for the Arduino to chill before starting.
|
|
for (uint8_t i = 1; i < ITERATIONS; i++) // Set the starting time for each iteration.
|
|
pingTimer[i] = pingTimer[i - 1] + PING_INTERVAL;
|
|
}
|
|
|
|
void loop() {
|
|
for (uint8_t i = 0; i < ITERATIONS; i++) { // Loop through all the iterations.
|
|
if (millis() >= pingTimer[i]) { // Is it this iteration's time to ping?
|
|
pingTimer[i] += PING_INTERVAL * ITERATIONS; // Set next time this sensor will be pinged.
|
|
if (i == 0 && currentIteration == ITERATIONS - 1) oneSensorCycle(); // Sensor ping cycle complete, do something with the results.
|
|
sonar.timer_stop(); // Make sure previous timer is canceled before starting a new ping (insurance).
|
|
currentIteration = i; // Sensor being accessed.
|
|
cm[currentIteration] = 0; // Make distance zero in case there's no ping echo for this iteration.
|
|
sonar.ping_timer(echoCheck); // Do the ping (processing continues, interrupt will call echoCheck to look for echo).
|
|
}
|
|
}
|
|
// Other code that *DOESN'T* analyze ping results can go here.
|
|
}
|
|
|
|
void echoCheck() { // If ping received, set the sensor distance to array.
|
|
if (sonar.check_timer())
|
|
cm[currentIteration] = sonar.ping_result / US_ROUNDTRIP_CM;
|
|
}
|
|
|
|
void oneSensorCycle() { // All iterations complete, calculate the median.
|
|
unsigned int uS[ITERATIONS];
|
|
uint8_t j, it = ITERATIONS;
|
|
uS[0] = NO_ECHO;
|
|
for (uint8_t i = 0; i < it; i++) { // Loop through iteration results.
|
|
if (cm[i] != NO_ECHO) { // Ping in range, include as part of median.
|
|
if (i > 0) { // Don't start sort till second ping.
|
|
for (j = i; j > 0 && uS[j - 1] < cm[i]; j--) // Insertion sort loop.
|
|
uS[j] = uS[j - 1]; // Shift ping array to correct position for sort insertion.
|
|
} else j = 0; // First ping is sort starting point.
|
|
uS[j] = cm[i]; // Add last ping to array in sorted position.
|
|
} else it--; // Ping out of range, skip and don't include as part of median.
|
|
}
|
|
Serial.print(uS[it >> 1]);
|
|
Serial.println("cm");
|
|
}
|